| Pacchetto | flash.globalization |
| Classe | public final class DateTimeFormatter |
| Ereditarietà | DateTimeFormatter  Object |
| Versione linguaggio: | ActionScript 3.0 |
| Versioni runtime: | Flash Player 10.1, AIR 2 |
Sono disponibili due modi per selezionare un formato di data e ora: utilizzare uno schema predefinito oppure uno personalizzato. Per la maggior parte delle applicazioni, devono essere utilizzati gli stili predefiniti specificati dalle costanti DateTimeStyle (LONG, MEDIUM, NONE o SHORT. Queste costanti consentono di specificare gli schemi predefiniti per le impostazioni internazionali richieste o gli schemi predefiniti basati sulle impostazioni del sistema operativo dell'utente.
Il codice seguente, ad esempio, crea una stringa relativa alla data utilizzando il formato di data breve predefinito:
var df:DateTimeFormatter = new DateTimeFormatter(LocaleID.DEFAULT, DateTimeStyle.SHORT, DateTimeStyle.NONE);
var currentDate:Date = new Date();
var shortDate:String = df.format(currentDate);
Quando viene creata un'istanza di questa classe, se le impostazioni internazionali richieste sono supportate dal sistema operativo, le proprietà dell'istanza vengono impostate in base alle convenzioni e alle impostazioni predefinite di tali impostazioni internazionali e in base ai parametri dateStyle e timeStyle della funzione di costruzione. Se le impostazioni internazionali richieste non sono disponibili, le proprietà vengono definite in base alle impostazioni internazionali di sistema predefinite o di riserva, che possono essere recuperate tramite la proprietà actualLocaleIDName.
Questa classe contiene metodi aggiuntivi per ottenere le stringhe localizzate dei nomi di mesi e giorni della settimana e per recuperare il primo giorno della settimana, che può essere utilizzato in un selettore per calendario o in un'altra applicazione simile.
In conseguenza dell'uso delle impostazioni dell'utente, degli schemi di formattazione forniti dal sistema operativo e delle impostazioni internazionali di riserva (quando quelle richieste non sono supportate), i risultati della formattazione saranno diversi da utente a utente, anche se utilizzano lo stesso ID di impostazioni internazionali.
Elementi API correlati
Nascondi proprietà pubbliche ereditate
Mostra proprietà pubbliche ereditate| Proprietà | Definito da | ||
|---|---|---|---|
| actualLocaleIDName : String [sola lettura]
Il nome dell'ID di impostazioni internazionali effettivamente utilizzato da questo oggetto DateTimeFormatter. | DateTimeFormatter | ||
 | constructor : Object
Un riferimento all'oggetto classe o alla funzione di costruzione per una determinata istanza di oggetto. | Object | |
| lastOperationStatus : String [sola lettura]
Lo stato della precedente operazione eseguita da questo oggetto DateTimeFormatter. | DateTimeFormatter | ||
| requestedLocaleIDName : String [sola lettura]
Il nome dell'ID di impostazioni internazionali richiesto che è stato passato alla funzione di costruzione di questo oggetto DateTimeFormatter. | DateTimeFormatter | ||
| Metodo | Definito da | ||
|---|---|---|---|
DateTimeFormatter(requestedLocaleIDName:String, dateStyle:String = "long", timeStyle:String = "long")
Costruisce un nuovo oggetto DateTimeFormatter per formattare le date e le ore in base alle convenzioni delle impostazioni internazionali specificate e agli stili di formattazione di data e ora forniti. | DateTimeFormatter | ||
Formatta una stringa di visualizzazione per un oggetto Date che viene interpretato come l'ora locale dell'utente (utilizzando i componenti dell'ora locale dell'oggetto Date quali: date, day, fullYear, hours, minutes, month e seconds). | DateTimeFormatter | ||
Formatta una stringa di visualizzazione per un oggetto Date che viene interpretato come ora universale (UTC) (utilizzando i componenti UTC dell'oggetto Date quali: dateUTC, dayUTC, fullYearUTC, hoursUTC, minutesUTC, monthUTC e secondsUTC), in base allo schema dateStyle, timeStyle o data/ora. | DateTimeFormatter | ||
[statico]
Elenca tutti i nomi degli ID di impostazioni internazionali supportati da questa classe. | DateTimeFormatter | ||
Ottiene lo stile della data per questa istanza di DateTimeFormatter. | DateTimeFormatter | ||
Restituisce la stringa di schema utilizzata da questo oggetto DateTimeFormatter per formattare date e ore. | DateTimeFormatter | ||
Restituisce un numero intero corrispondente al primo giorno della settimana per questo contesto locale e sistema di calendario. | DateTimeFormatter | ||
Recupera un elenco di stringhe localizzate contenenti i nomi dei mesi del sistema di calendario corrente. | DateTimeFormatter | ||
Ottiene lo stile dell'ora per questa istanza di DateTimeFormatter. | DateTimeFormatter | ||
Recupera un elenco di stringhe localizzate contenenti i nomi dei giorni della settimana del sistema di calendario corrente. | DateTimeFormatter | ||
|
Indica se per un oggetto è definita una proprietà specifica. | Object | |
|
Indica se un'istanza della classe Object si trova nella catena di prototipi dell'oggetto specificato come parametro. | Object | |
|
Indica se la proprietà specificata esiste ed è enumerabile. | Object | |
Imposta la stringa di schema utilizzata da questo oggetto DateTimeFormatter per formattare date e ore. | DateTimeFormatter | ||
Imposta gli stili di data e ora per questa istanza di DateTimeFormatter. | DateTimeFormatter | ||
|
Imposta la disponibilità di una proprietà dinamica per le operazioni cicliche. | Object | |
|
Restituisce la rappresentazione in formato stringa di questo oggetto, formattato in base alle convenzioni specifiche per le versioni localizzate. | Object | |
|
Restituisce la rappresentazione in formato stringa dell'oggetto specificato. | Object | |
|
Restituisce il valore di base dell'oggetto specificato. | Object | |
actualLocaleIDName | proprietà |
actualLocaleIDName:String [sola lettura] | Versione linguaggio: | ActionScript 3.0 |
| Versioni runtime: | Flash Player 10.1, AIR 2 |
Il nome dell'ID di impostazioni internazionali effettivamente utilizzato da questo oggetto DateTimeFormatter.
Esistono tre possibilità per il nome del valore, a seconda del sistema operativo e del valore del parametro requestedLocaleIDName passato alla funzione di costruzione Collator().
- Se le impostazioni internazionali richieste non corrispondevano al valore
LocaleID.DEFAULTe il sistema operativo fornisce il supporto per tali impostazioni internazionali, il nome restituito corrisponde alla proprietàrequestedLocaleIDName. - Se è stato utilizzato
LocaleID.DEFAULTcome valore del parametrorequestedLocaleIDNamepassato alla funzione di costruzione, viene utilizzato il nome delle impostazioni internazionali correnti specificato dal sistema operativo dell'utente. Il valoreLocaleID.DEFAULTmantiene l'impostazione personalizzata dell'utente nel sistema operativo. Se passate un valore esplicito come parametrorequestedLocaleIDName, non viene necessariamente restituito lo stesso risultato fornito daLocaleID.DEFAULT, anche se i nomi dei due ID di impostazioni internazionali sono gli stessi. L'utente potrebbe avere personalizzato le impostazioni internazionali del computer e la richiesta di un nome esplicito dell'ID di impostazioni internazionali, anziché l'utilizzo diLocaleID.DEFAULT, può impedire all'applicazione di rilevare tali impostazioni personalizzate. - Se il sistema operativo non supporta il parametro
requestedLocaleIDNamespecificato nella funzione di costruzione, viene fornito un nome dell'ID di impostazioni internazionali di riserva.
Implementazione
public function get actualLocaleIDName():StringElementi API correlati
lastOperationStatus | proprietà |
lastOperationStatus:String [sola lettura] | Versione linguaggio: | ActionScript 3.0 |
| Versioni runtime: | Flash Player 10.1, AIR 2 |
Lo stato della precedente operazione eseguita da questo oggetto DateTimeFormatter. La proprietà lastOperationStatus viene impostata ogni volta che chiamate una funzione di costruzione o un metodo di questa classe oppure impostate un'altra proprietà. Per i valori possibili, fate riferimento alla descrizione dei singoli metodi.
Implementazione
public function get lastOperationStatus():StringElementi API correlati
requestedLocaleIDName | proprietà |
requestedLocaleIDName:String [sola lettura] | Versione linguaggio: | ActionScript 3.0 |
| Versioni runtime: | Flash Player 10.1, AIR 2 |
Il nome dell'ID di impostazioni internazionali richiesto che è stato passato alla funzione di costruzione di questo oggetto DateTimeFormatter.
Se è stato utilizzato il valore LocaleID.DEFAULT, il nome restituito è "i-default". Quando vengono applicate impostazioni internazionali di riserva, le impostazioni internazionali effettivamente utilizzate possono essere diverse da quelle richieste. Il nome delle impostazioni internazionali effettive può essere recuperato utilizzando la proprietà actualLocaleIDName.
Implementazione
public function get requestedLocaleIDName():StringElementi API correlati
DateTimeFormatter | () | Funzione di costruzione |
public function DateTimeFormatter(requestedLocaleIDName:String, dateStyle:String = "long", timeStyle:String = "long")| Versione linguaggio: | ActionScript 3.0 |
| Versioni runtime: | Flash Player 10.1, AIR 2 |
Costruisce un nuovo oggetto DateTimeFormatter per formattare le date e le ore in base alle convenzioni delle impostazioni internazionali specificate e agli stili di formattazione di data e ora forniti. Gli stili di data e ora vengono utilizzati per impostare gli schemi di formattazione di data e ora in base agli schemi predefiniti e dipendenti dalle impostazioni internazionali del sistema operativo.
Questa funzione di costruzione determina se il sistema operativo corrente supporta il nome dell'ID di impostazioni internazionali richiesto. Se non è supportato, vengono utilizzate delle impostazioni internazionali di riserva. Il nome dell'ID di impostazioni internazionali di riserva può essere determinato dalla proprietà actualLocaleIDName.
Se vengono utilizzate le impostazioni internazionali di riserva per un parametro requestedLocaleIDName, dateStyle o timeStyle qualsiasi, la proprietà lastOperationStatus viene impostata di conseguenza, in modo da indicare tali impostazioni internazionali di riserva.
Per applicare la formattazione in base alle preferenze del sistema operativo corrente dell'utente, passate alla funzione di costruzione il valore LocaleID.DEFAULT nel parametro requestedLocaleIDName.
Quando la funzione di costruzione viene chiamata e completata correttamente, la proprietà lastOperationStatus viene impostata su:
LastOperationStatus.NO_ERROR
Quando il nome dell'ID di impostazioni internazionali richiesto non è disponibile, lastOperationStatus è impostata su uno dei valori seguenti:
LastOperationStatus.USING_FALLBACK_WARNINGLastOperationStatus.USING_DEFAULT_WARNING
Diversamente, la proprietà lastOperationStatus viene impostata su una delle costanti definite nella classe LastOperationStatus.
Per informazioni dettagliate sugli avvisi sopra indicati e altri possibili valori della proprietà lastOperationStatus, fate riferimento alle descrizioni disponibili nella classe LastOperationStatus.
requestedLocaleIDName:String — Il nome dell'ID di impostazioni internazionali preferite da utilizzare per determinare i formati di data e ora.
| |
dateStyle:String (default = "long")
| |
timeStyle:String (default = "long")
|
Genera
ArgumentError — Se il parametro dateStyle o timeStyle non è una costante DateTimeStyle valida.
| |
TypeError — Se il parametro dateStyle o timeStyle è null.
|
Elementi API correlati
format | () | metodo |
public function format(dateTime:Date):String| Versione linguaggio: | ActionScript 3.0 |
| Versioni runtime: | Flash Player 10.1, AIR 2 |
Formatta una stringa di visualizzazione per un oggetto Date che viene interpretato come l'ora locale dell'utente (utilizzando i componenti dell'ora locale dell'oggetto Date quali: date, day, fullYear, hours, minutes, month e seconds). La formattazione viene applicata in base alle convenzioni dell'ID di importazioni internazionali e allo stile di data e di ora, oppure in base a uno schema personalizzato per la data e per l'ora, specificati per questa istanza DateTimeFormatter.
Quando questo metodo viene chiamato e completato correttamente, la proprietà lastOperationStatus viene impostata su:
LastOperationStatus.NO_ERROR
Diversamente, la proprietà lastOperationStatus viene impostata su una delle costanti definite nella classe LastOperationStatus.
Parametri
dateTime:Date — Un valore Date da formattare. L'intervallo valido va dal 1 gennaio 1601 al 31 dicembre 30827.
|
String — Una stringa formattata che rappresenta il valore di data o di ora.
|
Elementi API correlati
formatUTC | () | metodo |
public function formatUTC(dateTime:Date):String| Versione linguaggio: | ActionScript 3.0 |
| Versioni runtime: | Flash Player 10.1, AIR 2 |
Formatta una stringa di visualizzazione per un oggetto Date che viene interpretato come ora universale (UTC) (utilizzando i componenti UTC dell'oggetto Date quali: dateUTC, dayUTC, fullYearUTC, hoursUTC, minutesUTC, monthUTC e secondsUTC), in base allo schema dateStyle, timeStyle o data/ora. La formattazione viene applicata in base alle convenzioni dell'ID di importazioni internazionali e allo stile di data e di ora, oppure in base a uno schema personalizzato per la data e per l'ora, specificati per questa istanza DateTimeFormatter.
Quando questo metodo viene chiamato e completato correttamente, la proprietà lastOperationStatus viene impostata su:
LastOperationStatus.NO_ERROR
Diversamente, la proprietà lastOperationStatus viene impostata su una delle costanti definite nella classe LastOperationStatus.
Parametri
dateTime:Date — Un valore Date da formattare. L'intervallo valido va dal 1 gennaio 1601 al 31 dicembre 30827.
|
String — Una stringa formattata che rappresenta il valore di data o di ora.
|
Elementi API correlati
getAvailableLocaleIDNames | () | metodo |
public static function getAvailableLocaleIDNames():Vector.<String>| Versione linguaggio: | ActionScript 3.0 |
| Versioni runtime: | Flash Player 10.1, AIR 2 |
Elenca tutti i nomi degli ID di impostazioni internazionali supportati da questa classe.
Se questa classe non è supportata dal sistema operativo corrente, il metodo restituisce un valore null.
Quando questo metodo viene chiamato e completato correttamente, la proprietà lastOperationStatus viene impostata su:
LastOperationStatus.NO_ERROR
Diversamente, la proprietà lastOperationStatus viene impostata su una delle costanti definite nella classe LastOperationStatus.
Vector.<String> — Un vettore di stringhe contenente tutti i nomi degli ID di impostazioni internazionali supportati da questa classe.
|
Elementi API correlati
getDateStyle | () | metodo |
public function getDateStyle():String| Versione linguaggio: | ActionScript 3.0 |
| Versioni runtime: | Flash Player 10.1, AIR 2 |
Ottiene lo stile della data per questa istanza di DateTimeFormatter. Lo stile della data viene utilizzato per recuperare dal sistema operativo uno schema di formattazione della data predefinito. Il valore dello stile della data può essere impostato dalla funzione di costruzione DateTimeFormatter(), dal metodo setDateTimeStyles() o dal metodo setDateTimePattern().
Quando questo metodo viene chiamato e completato correttamente, la proprietà lastOperationStatus viene impostata su:
LastOperationStatus.NO_ERROR
Diversamente, la proprietà lastOperationStatus viene impostata su una delle costanti definite nella classe LastOperationStatus.
String — La stringa con lo stile della data per questa classe di formattazione.
Valori possibili:
|
Elementi API correlati
getDateTimePattern | () | metodo |
public function getDateTimePattern():String| Versione linguaggio: | ActionScript 3.0 |
| Versioni runtime: | Flash Player 10.1, AIR 2 |
Restituisce la stringa di schema utilizzata da questo oggetto DateTimeFormatter per formattare date e ore.
Potete impostare questo schema in uno dei tre modi seguenti:
- Tramite i parametri
dateStyleetimeStyleutilizzati nella funzione di costruzione. - Tramite il metodo
setDateTimeStyles(). - Tramite il metodo
setDateTimePattern().
Per una descrizione della sintassi dello schema, fate riferimento al metodo setDateTimePattern().
Quando questo metodo viene chiamato e completato correttamente, la proprietà lastOperationStatus viene impostata su:
LastOperationStatus.NO_ERROR
Diversamente, la proprietà lastOperationStatus viene impostata su una delle costanti definite nella classe LastOperationStatus.
String — Una stringa contenente lo schema utilizzato da questo oggetto DateTimeFormatter per formattare date e ore.
|
Elementi API correlati
getFirstWeekday | () | metodo |
public function getFirstWeekday():int| Versione linguaggio: | ActionScript 3.0 |
| Versioni runtime: | Flash Player 10.1, AIR 2 |
Restituisce un numero intero corrispondente al primo giorno della settimana per questo contesto locale e sistema di calendario. Un valore 0 corrisponde a domenica, 1 corrisponde a lunedì e così via; 6 corrisponde a sabato.
Quando questo metodo viene chiamato e completato correttamente, la proprietà lastOperationStatus viene impostata su:
LastOperationStatus.NO_ERROR
Diversamente, la proprietà lastOperationStatus viene impostata su una delle costanti definite nella classe LastOperationStatus.
int — Un numero intero corrispondente al primo giorno della settimana per questo contesto locale e sistema di calendario.
|
Elementi API correlati
getMonthNames | () | metodo |
public function getMonthNames(nameStyle:String = "full", context:String = "standalone"):Vector.<String>| Versione linguaggio: | ActionScript 3.0 |
| Versioni runtime: | Flash Player 10.1, AIR 2 |
Recupera un elenco di stringhe localizzate contenenti i nomi dei mesi del sistema di calendario corrente. Il primo elemento nell'elenco rappresenta il nome del primo mese dell'anno.
Quando questo metodo viene chiamato e completato correttamente, la proprietà lastOperationStatus viene impostata su:
LastOperationStatus.NO_ERROR
Diversamente, la proprietà lastOperationStatus viene impostata su una delle costanti definite nella classe LastOperationStatus.
Parametri
nameStyle:String (default = "full")
| |
context:String (default = "standalone")
|
Vector.<String> — Un vettore di stringhe localizzate contenenti i nomi dei mesi per le impostazioni internazionali, lo stile dei nomi e il contesto specificati. Il primo elemento nel vettore, nella posizione di indice 0, corrisponde al nome del primo mese dell'anno; l'elemento successivo è il nome del secondo mese dell'anno e così via.
|
Genera
TypeError — Se il parametro nameStyle o context è null.
|
Elementi API correlati
getTimeStyle | () | metodo |
public function getTimeStyle():String| Versione linguaggio: | ActionScript 3.0 |
| Versioni runtime: | Flash Player 10.1, AIR 2 |
Ottiene lo stile dell'ora per questa istanza di DateTimeFormatter. Lo stile dell'ora viene utilizzato per recuperare dal sistema operativo uno schema di formattazione dell'ora predefinito. Il valore dello stile dell'ora può essere impostato dalla funzione di costruzione DateTimeFormatter(), dal metodo setDateTimeStyles() o dal metodo setDateTimePattern().
Quando questo metodo viene chiamato e completato correttamente, la proprietà lastOperationStatus viene impostata su:
LastOperationStatus.NO_ERROR
Diversamente, la proprietà lastOperationStatus viene impostata su una delle costanti definite nella classe LastOperationStatus.
String — La stringa con lo stile dell'ora per questa classe di formattazione.
Valori possibili:
|
Elementi API correlati
getWeekdayNames | () | metodo |
public function getWeekdayNames(nameStyle:String = "full", context:String = "standalone"):Vector.<String>| Versione linguaggio: | ActionScript 3.0 |
| Versioni runtime: | Flash Player 10.1, AIR 2 |
Recupera un elenco di stringhe localizzate contenenti i nomi dei giorni della settimana del sistema di calendario corrente. Il primo elemento nell'elenco rappresenta il nome per domenica.
Quando questo metodo viene chiamato e completato correttamente, la proprietà lastOperationStatus viene impostata su:
LastOperationStatus.NO_ERROR
Diversamente, la proprietà lastOperationStatus viene impostata su una delle costanti definite nella classe LastOperationStatus.
Parametri
nameStyle:String (default = "full")
| |
context:String (default = "standalone")
|
Vector.<String> — Un vettore di stringhe localizzate contenenti i nomi dei mesi per le impostazioni internazionali, lo stile dei nomi e il contesto specificati. Il primo elemento nel vettore, nella posizione di indice 0, corrisponde al nome per domenica; l'elemento successivo è il nome per lunedì e così via.
|
Genera
TypeError — Se il parametro nameStyle o context è null.
|
Elementi API correlati
setDateTimePattern | () | metodo |
public function setDateTimePattern(pattern:String):void| Versione linguaggio: | ActionScript 3.0 |
| Versioni runtime: | Flash Player 10.1, AIR 2 |
Imposta la stringa di schema utilizzata da questo oggetto DateTimeFormatter per formattare date e ore.
Potete impostare lo schema utilizzato per formattare le date in uno dei tre modi seguenti:
- Tramite i parametri
dateStyleetimeStyleutilizzati nella funzione di costruzione. - Tramite il metodo
setDateTimeStyles(). - Tramite questo metodo
setDateTimePattern().
come effetto collaterale, questo metodo ignora gli stili di data e ora correnti per questo oggetto DateTimeFormatter e imposta il relativo valore su DateTimeStyle.CUSTOM.
Una stringa di schema consente di definire la formattazione di date e ore. Lo schema contiene sequenze di lettere che vengono sostituite con valori di data e di ora nella stringa formattata. Nello schema "yyyy/MM", ad esempio, i caratteri "yyyy" vengono sostituiti con un anno a quattro cifre, seguito dal carattere "/", e i caratteri "MM" vengono sostituiti da un mese a due cifre.
Molte delle lettere utilizzate in uno schema possono essere ripetute più volte per produrre output diversi, come descritto nella tabella seguente.
Se una sequenza eccede il numero massimo di lettere supportato da uno schema, viene associata automaticamente alla sequenza più lunga supportata per tale lettera nello schema. Ad esempio:
- MMMMMM viene sostituito con MMMM;
- dddd viene sostituito con dd;
- EEEEEEE viene sostituito con EEEE;
- aa viene sostituito con a;
- hhh viene sostituito con hh;
- mmmm viene sostituito con mm.
Teoricamente, uno schema può contenere fino a 255 caratteri, ma alcune piattaforme presentano limiti più restrittivi. Se lo schema eccede il limite di caratteri supportato, la proprietà lastOperationStatus viene impostato sul valore LastOperationStatus.PATTERN_SYNTAX_ERROR.
Non tutti i possibili schemi sono supportati su tutti i sistemi operativi. Se un dato schema non è supportato sulla piattaforma in uso, viene utilizzato uno schema di riserva e la proprietà lastOperationStatus viene impostata in modo da indicare l'uso di uno schema di riserva. Se non è possibile fornire uno schema di riserva adeguato, viene utilizzata una stringa vuota e la proprietà lastOperationStatus viene impostata in modo da indicare che lo schema non è supportato.
Nella seguente tabella sono descritte le lettere valide per lo schema e il relativo significato.
| Lettera dello schema | Descrizione |
| G | Era. Sostituita dalla stringa relativa all'era per la data e il calendario correnti. Questo schema non è supportato su tutti i sistemi operativi. Nei sistemi operativi che non supportano l'indicazione dell'era, le lettere dello schema di input vengono sostituite da una stringa vuota.
Negli schemi che supportano l'era possono essere presenti da una a cinque lettere che vengono interpretate come segue:
Esempi con il calendario gregoriano per i sistemi operativi che supportano questo schema:
|
| y | Anno. Se il numero di lettere dello schema è due, vengono visualizzate le ultime due cifre dell'anno; diversamente, il numero di lettere è determinato dal numero di cifre. Se il valore dell'anno richiede più cifre di quelle fornite in base al numero di lettere, viene fornito il valore corrispondente all'anno completo. Se sono presenti più lettere di quelle richieste dal valore, i valori relativi all'anno vengono riempiti con zeri. Nell'elenco seguente sono riportati i risultati per gli anni 1 e 2005.
Esempi:
|
| M | Mese dell'anno. Negli schemi che supportano il mese possono essere presenti da una a cinque lettere che vengono interpretate come segue:
Esempi:
|
| d | Giorno del mese. Negli schemi che supportano il giorno del mese possono essere presenti una o due lettere che vengono interpretate come segue:
Esempi:
|
| E | Giorno della settimana. Negli schemi che supportano il giorno della settimana possono essere presenti una o cinque lettere che vengono interpretate come segue:
Esempi:
|
| Q | Trimestre. Alcune piattaforme non supportano questo schema. Negli schemi che supportano il trimestre possono essere presenti da una a quattro lettere che vengono interpretate come segue:
Esempi (per i sistemi operativi che supportano questo schema):
|
| w | Settimana dell'anno. Alcune piattaforme non supportano questo schema. In questo schema possono essere presenti da una a due lettere che vengono interpretate come segue:
Esempi per la seconda settimana dell'anno (per i sistemi operativi che supportano questo schema):
|
| W | Settimana del mese. Alcune piattaforme non supportano questo schema. Questo schema consente l'uso di una sola lettera.
Esempi per la seconda settimana di luglio (per i sistemi operativi che supportano questo schema):
|
| D | Giorno dell'anno. Alcune piattaforme non supportano questo schema. In questo schema possono essere presenti da una a tre lettere.
Esempi per il secondo giorno dell'anno (per i sistemi operativi che supportano questo schema):
|
| F | Occorrenza di un giorno della settimana in un mese calendario. Questo elemento visualizza, ad esempio, "3" se utilizzato per formattare la data del terzo lunedì di ottobre. Questo schema consente l'uso di una sola lettera.
Esempi per il secondo mercoledì di luglio (per i sistemi operativi che supportano questo schema):
|
| a | Indicatore di AM/PM. Questo schema consente l'uso di una sola lettera, a o p.
Esempi:
|
| h | Ora del giorno nel formato a 12 ore [1 - 12]. Questo schema consente l'uso di una o due lettere.
Esempi:
|
| H | Ora del giorno nel formato a 24 ore [0 - 23]. Questo schema consente l'uso di una o due lettere.
Esempi:
|
| K | Ora del giorno nel formato a 12 ore [0 - 11]. Questo schema consente l'uso di una o due lettere. Questo schema non è supportato su tutti i sistemi operativi.
Esempi (per i sistemi operativi che supportano questo schema):
|
| k | Ora del giorno nel formato a 24 ore [1 - 24]. Questo schema consente l'uso di una o due lettere. Questo schema non è supportato su tutti i sistemi operativi.
Esempi (per i sistemi operativi che supportano questo schema):
|
| m | Minuto dell'ora [0 - 59]. Questo schema consente l'uso di una o due lettere.
Esempi:
|
| s | Secondi del minuto [0 - 59]. Questo schema consente l'uso di una o due lettere.
Esempi:
|
| S | Millisecondi. Per questo schema devono essere utilizzate da una a cinque lettere. Il valore viene arrotondato in base al numero di lettere utilizzato. L'utilizzo di cinque caratteri (SSSSS) indica millisecondi frazionari.
Esempi:
|
| z | Fuso orario. Rappresenta il fuso orario sotto forma di stringa che rispetta l'ora legale o solare, senza fare riferimento a una località specifica. Questo schema non è supportato su tutti i sistemi operativi. Nei sistemi operativi che non supportano l'indicazione del fuso orario, le lettere dello schema di input vengono sostituite da una stringa vuota. Nei sistemi operativi che non supportano questo schema, non viene definita una stringa per tutte le impostazioni internazionali. Per tali impostazioni internazionali viene utilizzato il formato GMT, ad esempio GMT-08.00 o GW-08.00
In questo schema del fuso orario devono essere presenti da una a quattro lettere che vengono interpretate come segue:
Esempi per i sistemi operativi che supportano questo formato:
|
| Z | Fuso orario. Rappresenta il fuso orario come differenza (offset) da GMT. Questo schema non è supportato su tutti i sistemi operativi. Nei sistemi operativi che non supportano l'indicazione del fuso orario, le lettere dello schema di input vengono sostituite da una stringa vuota.
In questo schema del fuso orario devono essere presenti da una a quattro lettere che vengono interpretate come segue:
Esempi per i sistemi operativi che supportano questo formato:
|
| v | Fuso orario. Una stringa che riflette il fuso orario generico che non si riferisce a una località specifica o distingue l'ora solare dall'ora legale. Questo schema non è supportato su tutti i sistemi operativi. Nei sistemi operativi che non supportano l'indicazione del fuso orario, le lettere dello schema di input vengono sostituite da una stringa vuota. Nei sistemi operativi che supportano tale schema, vengono fornite stringhe di riserva se non è disponibile un nome localizzato.
In questo schema del fuso orario devono essere presenti una o quattro lettere che vengono interpretate come segue:
Esempi per i sistemi operativi che supportano questo formato:
|
| 'Altro testo' | Il testo e la punteggiatura possono essere inclusi nella stringa di schema. I caratteri da a a z e da A a Z sono tuttavia riservati per la sintassi e, per poter essere inclusi nella stringa formattata, devono essere racchiusi tra virgolette singole. Per includere una virgoletta singola nella stringa risultante, nella stringa di schema devono essere utilizzate due virgolette singole. Le due virgolette singole possono essere visualizzate all'interno o all'esterno di una parte tra virgolette della stringa di schema. Una coppia di virgolette semplici non chiuse viene terminata alla fine della stringa.
Esempi:
|
Quando questo metodo viene chiamato e completato correttamente, la proprietà lastOperationStatus viene impostata su:
LastOperationStatus.NO_ERROR
Diversamente, la proprietà lastOperationStatus viene impostata su una delle costanti definite nella classe LastOperationStatus.
Parametri
pattern:String |
Genera
TypeError — Se il parametro pattern è null.
|
Elementi API correlati
setDateTimeStyles | () | metodo |
public function setDateTimeStyles(dateStyle:String, timeStyle:String):void| Versione linguaggio: | ActionScript 3.0 |
| Versioni runtime: | Flash Player 10.1, AIR 2 |
Imposta gli stili di data e ora per questa istanza di DateTimeFormatter. Gli stili di data e ora vengono utilizzati per impostare gli schemi di formattazione di data e ora in base agli schemi predefiniti e dipendenti dalle impostazioni internazionali del sistema operativo. Questo metodo sostituisce gli stili che sono stati impostati utilizzando la funzione di costruzione DateTimeFormatter() o il metodo setDateTimePattern(). In base agli stili impostati, viene aggiornato anche lo schema di data e ora.
Quando questo metodo viene chiamato e completato correttamente, la proprietà lastOperationStatus viene impostata su:
LastOperationStatus.NO_ERROR
Diversamente, la proprietà lastOperationStatus viene impostata su una delle costanti definite nella classe LastOperationStatus.
Parametri
dateStyle:String — Specifica lo stile da utilizzare per la formattazione delle date. Il valore corrisponde a uno dei valori enumerati dalla classe DateTimeStyle:
| |
timeStyle:String — Specifica lo stile da utilizzare per la formattazione delle ore. Il valore corrisponde a uno dei valori enumerati dalla classe DateTimeStyle:
|
Genera
ArgumentError — Se il parametro dateStyle o timeStyle non è una costante DateTimeStyle valida.
| |
TypeError — Se il parametro dateStyle o timeStyle è null.
|
Elementi API correlati
In questo esempio vengono utilizzate le seguenti impostazioni internazionali: inglese (Stati Uniti), francese (Francia), spagnolo (Spagna).
Nell'esempio vengono effettuate le seguenti operazioni per ogni contesto di impostazioni internazionali incluso nell'elenco:
- Crea un oggetto DateTimeFormatter utilizzando lo stile predefinito (dateStyle lungo, timeStyle lungo)
- Formatta la data e l'ora correnti utilizzando lo stile data lungo.
- Commuta su uno stile di data con indicazione esclusivamente dell'orario utilizzando le costanti
DateTimeStyle.NONEeDateTimeStyle.SHORT. - Formatta la data e l'ora correnti utilizzando lo stile data corto con indicazione solo dell'ora.
package {
import flash.display.Sprite;
import flash.globalization.DateTimeFormatter;
import flash.globalization.DateTimeStyle;
public class DateTimeFormatterExample extends Sprite
{
private var localeList:Array = new Array("en-US", "fr-FR", "es-ES");
public function DateTimeFormatterExample()
{
var date:Date = new Date();
for each (var locale:String in localeList) {
var dtf:DateTimeFormatter = new DateTimeFormatter(locale);
trace('\n' + "LocaleID requested=" + dtf.requestedLocaleIDName
+ "; actual=" + dtf.actualLocaleIDName);
var longDate:String = dtf.format(date);
trace(longDate + " (" + dtf.getDateTimePattern() + ")");
dtf.setDateTimeStyles(DateTimeStyle.NONE, DateTimeStyle.SHORT);
var shortDate:String = dtf.format(date);
trace(shortDate + " (" + dtf.getDateTimePattern() + ")");
}
}
}
}
Nell'esempio vengono effettuate le seguenti operazioni per ogni contesto di impostazioni internazionali incluso nell'elenco:
- Crea tre campi di testo di input e output.
- Crea un oggetto DateTimeFormatter utilizzando le impostazioni internazionali per la lingua inglese americana.
- Chiama la funzione
configureTextField(), che imposta la posizione e le dimensioni dei campi di testo e aggiunge un listener di eventi all'oggettopatternField. - Quando l'utente immette lo schema nel campo di testo
patternField, la funzionetextInputHandlerformatta la data e l'ora correnti utilizzando lo schema e visualizza il risultato e il valorelastOperationStatusnei campi di testo di output.
package {
import flash.display.Sprite;
import flash.events.Event;
import flash.globalization.DateTimeFormatter;
import flash.text.*;
public class DateTimePatternExample extends Sprite
{
private var patternField:TextField = new TextField();
private var resultField:TextField = new TextField();
private var statusField:TextField = new TextField();
private var date:Date = new Date();
private var dtf:DateTimeFormatter = new DateTimeFormatter("en-US");
private function configureTextField():void
{
patternField.type = TextFieldType.INPUT;
patternField.width = 300;
patternField.height = 20;
patternField.background = true;
patternField.border = true;
resultField.y = 40;
resultField.width = 300;
resultField.height = 20;
statusField.y = 80;
statusField.width = 300;
statusField.height = 20;
addChild(patternField);
addChild(resultField);
addChild(statusField);
patternField.addEventListener(Event.CHANGE,textInputHandler);
}
private function textInputHandler(event:Event):void
{
dtf.setDateTimePattern(patternField.text);
statusField.text = dtf.lastOperationStatus;
resultField.text = dtf.format(date);
}
public function DateTimePatternExample()
{
configureTextField();
}
}
}
Tue Jun 12 2018, 02:44 PM Z